The RTD of a continuous reactor is found by tracer experiment and is given by

E(θ) = (e^(-θ))

where the dimensionless time is θ  = vt/V.

The reactor is used to carry out the decomposition of a substance A in solution. This reaction is irreversible and of zero order with rate constant k=0.5 kmol/m^3/h. If the feed concentration is 2.0 kmol/m^3 and its flow rate is 10 m^3/h, use the above RTD to estimate the concentration of A in the effluent from the reactor, whose volume is 30 m^3.

Compare the result with that for an ideal MFR. Repeat the calculations for k=0.2 and 0.05 kmol/m^3/h. Comment on the degree of agreement (or disagreement?).

(I have adapted this problem from Denbigh and Turner's "Chemical Reactor Theory," 1984, pp. 107-108.)

k1 = 0.5;
k2 = 0.2;
k3 = 0.05;
v = 10;
volume = 30;
cA0 = 2;
tau = volume/v
theta = time/tau;
eFunction1 = Exp[-theta];
eFunction2 = 1/tau*Exp[-time/tau];
sigma = 
      Sqrt[Integrate[(time - tau)^2*1/tau*eFunction1, {time, 0, 
            Infinity}]]
Plot[eFunction1, {time, 0, 10}];

Note that the standard deviation (σ) in a perfect MFR is as large as the value of the mean, i.e., as the average residence time! This is indeed the largest possible deviation from perfect plug flow.

cAoverCa01 = 1 - k1*time/cA0;
cAoverCa02 = 1 - k2*time/cA0;
cAoverCa03 = 1 - k3*time/cA0;
Plot[{cAoverCa01, cAoverCa02, cAoverCa03, eFunction1}, {time, 0, 40}, 
        PlotRange -> {0, 1}, 
        PlotStyle -> {Thickness[0.004], Thickness[0.007], 
            Thickness[0.01], Thickness[0.013]}];

cAoverCA011 = (1 - k1*tau/cA0)
cAoverCA012 = 
      Integrate[(1 - k1*time/cA0)*eFunction2, {time, 0, 4}]

cAoverCA021 = (1 - k2*tau/cA0)
cAoverCA022 = 
      Integrate[(1 - k2*time/cA0)*eFunction2, {time, 0, 10}]

cAoverCA031 = (1 - k3*tau/cA0)
cAoverCA032 = 
      Integrate[(1 - k3*time/cA0)*eFunction2, {time, 0, 40}]

Let's now see what happens for 1st order reactions, similar to the analysis that we did in "NonidealConv.nb".

cAoverCA0First1 = Exp[-k1*time];
cAoverCA0First2 = Exp[-k2*time];
cAoverCA0First3 = Exp[-k3*time];
Plot[{cAoverCA0First1, cAoverCA0First2, cAoverCA0First3, 
          eFunction1}, {time, 0, 10}, PlotRange -> {0, 1}, 
        PlotStyle -> {Thickness[0.004], Thickness[0.007], 
            Thickness[0.010], Thickness[0.013]}];

cAoverCA0First11 = 
      Integrate[Exp[-k1*time]*eFunction2, {time, 0, Infinity}] // 
        N
cAoverCA0First12 = 1/(1 + k1*tau)
cAoverCA0First21 = 
      Integrate[Exp[-k2*time]*eFunction2, {time, 0, Infinity}] // 
        N
cAoverCA0First22 = 1/(1 + k2*tau)
cAoverCA0First31 = 
      Integrate[Exp[-k3*time]*eFunction2, {time, 0, Infinity}] // 
        N
cAoverCA0First32 = 1/(1 + k3*tau)

So for 1st order reactions, despite the fact that for k1=0.5 the reaction time is shorter than the mixing time (maximum residence time), the RTD/segregated flow model gives the right result (at all conversion levels).

Let's now see what happens for 2nd order reactions, using the same type of analysis.

cAoverCA0Two1 = 1/(1 + cA0*k1*time);
cAoverCA0Two2 = 1/(1 + cA0*k2*time);
cAoverCA0Two3 = 1/(1 + cA0*k3*time);
Plot[{cAoverCA0Two1, cAoverCA0Two2, cAoverCA0Two3, 
          eFunction1}, {time, 0, 10}, PlotRange -> {0, 1}, 
        PlotStyle -> {Thickness[0.004], Thickness[0.007], 
            Thickness[0.010], Thickness[0.013]}];

Solve[kTau == xA/(cA0*(1 - xA)^2), xA]

cAoverCA0Two11 = 
      Integrate[1/(1 + cA0*k1*time)*eFunction2, {time, 0, Infinity}] // 
        N
cAoverCA0Two12 = 
      1 - ((1 + 4 k1*tau - (Sqrt[1 + 8 k1*tau]))/(4 k1*tau))
cAoverCA0Two21 = 
      Integrate[1/(1 + cA0*k2*time)*eFunction2, {time, 0, Infinity}] // 
        N
cAoverCA0Two22 = 
      1 - ((1 + 4 k2*tau - (Sqrt[1 + 8 k2*tau]))/(4 k2*tau))
cAoverCA0Two31 = 
      Integrate[1/(1 + cA0*k3*time)*eFunction2, {time, 0, Infinity}] // 
        N
cAoverCA0Two32 = 
      1 - ((1 + 4 k3*tau - (Sqrt[1 + 8 k3*tau]))/(4 k3*tau))

Here we see that as the reaction time decreases and becomes comparable to the mixing time, or as the degree of conversion increases, the inaccuracy  of the RTD/segregated flow model result increases.

The following important conclusion is clear from this analysis: 
When the reaction time is smaller than the "mixing time," and especially at high conversion levels, knowledge of the RTD and use of the segregated flow model is insufficient to determine reactor performance (except for 1st order reactions). The spatial and temporal details of mixing and the degree of segregation must be known as well. But that's beyond the scope of our introductory CRE course...

This analysis emphasizes the importance of mixing, or mass transfer (diffusion and convection), in reactor analysis and design, even for homogeneous reactions:

When mass transfer becomes the rate-determining step, i.e., when the rate constant for mass transfer (mixing) is smaller than the rate constant for chemical reaction (or when the characteristic mass transfer time is longer than the characteristic reaction time), reactor performance depends as much (or more!) on mixing (degree of segregation, earliness of mixing) as on chemical kinetics.

In heterogeneous reactions, which are the next topic of our discussion, this interplay between mass transfer and chemical reaction is THE most important issue.

LRR3@psu.edu